Wronskian criterion for interlacing

For real-rooted polynomials with positive leading coefficients and degrees differing by at most one, $g$ interlaces $f$ if and only if the Wronskian $f'g-fg'$ is nonnegative on $\mathbb R$ and no zero of $f$ has multiplicity more than one above its multiplicity in $g$.

Results

Let $W(g,f)=f'g-fg'$, and let $\mathrm{mult}_r(p)$ be the multiplicity of $r$ as a zero of $p$, which is $0$ if $p(r)\ne0$.

Theorem (Wronskian criterion). Let $f,g$ be real-rooted with positive leading coefficients and $\deg g\le\deg f\le\deg g+1$. Then $g\ll f$ if and only if $$ W(g,f)(x)\ge0\ \text{ for all }x\in\mathbb R\quad\text{and}\quad \mathrm{mult}_r(f)\le\mathrm{mult}_r(g)+1\ \text{ for all }r\in\mathbb R . $$ The forward direction holds for every pair with $g\ll f$ and positive leading coefficients. The converse also holds when all zeros of $f$ are simple, without the multiplicity condition.

Example. The multiplicity condition cannot be dropped: for $f=(x-1)^3$ and $g=x^3$ we have $W(g,f)=3x^2(x-1)^2\ge0$, but $g\ll f$ fails.

Theorem (strict converses). Let $f,g$ be real-rooted with positive leading coefficients and $W(g,f)(x)>0$ for all $x\in\mathbb R$.

Theorem (Laguerre's inequality). If $p$ is real-rooted, then for all $t\in\mathbb R$, $$ p'(t)^2-p(t)\,p''(t)\ge0 , $$ that is, $W(p,p')\le0$. Moreover $$ p'(t)^2\le\deg(p)\,\bigl(p'(t)^2-p(t)\,p''(t)\bigr), $$ and $(M-1)\,p'(t)^2\ge M\,p(t)\,p''(t)$ for every $M\ge\deg p$.

Proof

Common zeros are removed one at a time, using $W(hg,hf)=h^2W(g,f)$. Without common zeros, a positive Wronskian is handled by the Bézout matrix in equal degree and by padding in successor degree.

References

See [Fis06] and the Wronskian criterion in the interlacing overview on symmetricfunctions.com.

  1. [Fis06] Steve Fisk. Polynomials, roots, and interlacing. arXiv e-prints, 2006.
    BibTeX
    @article{Fisk2006x,
      Author = {Steve Fisk},
      Title = {Polynomials, roots, and interlacing},
      Year = {2006},
      Eprint = {arXiv:math/0612833},
      journal = {arXiv e-prints}
    }

Theorems

  • Interlacing is a nonnegative Wronskian plus a multiplicity boundMain result

    RealRooted.strictInterl_iff_wronskian_eval_nonnegsourcestatement on symmetricfunctions.com
    theorem strictInterl_iff_wronskian_eval_nonneg {f g : ℝ[X]}
        (hf_pos : HasPosLeadingCoeff f) (hg_pos : HasPosLeadingCoeff g)
        (hf_splits : f.Splits) (hg_splits : g.Splits)
        (hdeg_le : g.natDegree ≤ f.natDegree) (hdeg : f.natDegree ≤ g.natDegree + 1) :
        StrictInterl g f ↔
          (∀ t, 0 ≤ (wronskian g f).eval t) ∧
            ∀ r, f.rootMultiplicity r ≤ g.rootMultiplicity r + 1
  • A nonnegative Wronskian and the multiplicity bound give interlacing

    RealRooted.strictInterl_of_wronskian_eval_nonnegsource
    theorem strictInterl_of_wronskian_eval_nonneg {f g : ℝ[X]}
        (hf_pos : HasPosLeadingCoeff f) (hg_pos : HasPosLeadingCoeff g)
        (hf_splits : f.Splits) (hg_splits : g.Splits)
        (hdeg_le : g.natDegree ≤ f.natDegree) (hdeg : f.natDegree ≤ g.natDegree + 1)
        (hmult : ∀ r, f.rootMultiplicity r ≤ g.rootMultiplicity r + 1)
        (hW : ∀ t, 0 ≤ (wronskian g f).eval t) : StrictInterl g f
  • Interlacing gives a nonnegative Wronskian

    RealRooted.wronskian_eval_nonneg_of_strictInterlsource
    theorem wronskian_eval_nonneg_of_strictInterl {p q : ℝ[X]}
        (hp_pos : HasPosLeadingCoeff p) (hq_pos : HasPosLeadingCoeff q)
        (hstrictInterl : StrictInterl q p) (t : ℝ) :
        0 ≤ (Polynomial.wronskian q p).eval t
  • A nonnegative Wronskian gives interlacing when f has simple zeros

    RealRooted.strictInterl_of_wronskian_eval_nonneg_of_nodupsource
    theorem strictInterl_of_wronskian_eval_nonneg_of_nodup {f g : ℝ[X]}
        (hf_pos : HasPosLeadingCoeff f) (hg_pos : HasPosLeadingCoeff g)
        (hf_splits : f.Splits) (hg_splits : g.Splits)
        (hdeg_le : g.natDegree ≤ f.natDegree) (hdeg : f.natDegree ≤ g.natDegree + 1)
        (hf_nodup : f.roots.Nodup)
        (hW : ∀ t, 0 ≤ (wronskian g f).eval t) : StrictInterl g f
  • A positive Wronskian gives strict interlacing in equal degree

    RealRooted.StrictInterlSameDegree.of_wronskian_possource
    lemma StrictInterlSameDegree.of_wronskian_pos {n : ℕ}
        {p q : ℝ[X]} (hp_pos : HasPosLeadingCoeff p) (hq_pos : HasPosLeadingCoeff q)
        (hp_deg : p.natDegree = n) (hq_deg : q.natDegree = n)
        (hp_splits : p.Splits) (hq_splits : q.Splits)
        (hW : ∀ t : ℝ, 0 < q.derivative.eval t * p.eval t -
        q.eval t * p.derivative.eval t) :
        StrictInterlSameDegree p q
  • A positive Wronskian gives interlacing in successor degree

    RealRooted.strictInterl_of_wronskian_pos_succsource
    lemma strictInterl_of_wronskian_pos_succ {n : ℕ}
        {p q : ℝ[X]} (hp_pos : HasPosLeadingCoeff p) (hq_pos : HasPosLeadingCoeff q)
        (hp_deg : p.natDegree = n + 1) (hq_deg : q.natDegree = n)
        (hp_splits : p.Splits) (hq_splits : q.Splits)
        (hW : ∀ t : ℝ, 0 < p.derivative.eval t * q.eval t - p.eval t * q.derivative.eval t) :
        StrictInterl q p
  • Laguerre's inequality

    RealRooted.laguerre_form_nonnegsource
    theorem laguerre_form_nonneg {p : ℝ[X]} (hp : p.Splits) (t : ℝ) :
        0 ≤ (derivative p).eval t ^ 2 -
          p.eval t * (derivative (derivative p)).eval t
  • Degree-weighted Laguerre inequality p'² ≤ deg p · (p'² − p p'')

    RealRooted.derivative_sq_le_natDegree_mul_laguerreFormsource
    theorem derivative_sq_le_natDegree_mul_laguerreForm {p : ℝ[X]}
        (hp : p.Splits) (t : ℝ) :
        (derivative p).eval t ^ 2 ≤
          (p.natDegree : ℝ) * (laguerreForm p).eval t
  • Polar Laguerre inequality (M − 1) p'² ≥ M p p'' for M ≥ deg p

    RealRooted.polar_laguerreForm_nonnegsource
    theorem polar_laguerreForm_nonneg {p : ℝ[X]} (hp : p.Splits) {M : ℕ}
        (hdeg : p.natDegree ≤ M) (t : ℝ) :
        0 ≤ ((M : ℝ) - 1) * (derivative p).eval t ^ 2 -
          (M : ℝ) * (p.eval t * (derivative (derivative p)).eval t)
  • The multiplicity condition cannot be dropped: (x − 1)³ and x³

    RealRooted.exists_wronskian_eval_nonneg_not_strictInterlsource
    theorem exists_wronskian_eval_nonneg_not_strictInterl :
        ∃ f g : ℝ[X], HasPosLeadingCoeff f ∧ HasPosLeadingCoeff g ∧ f.Splits ∧ g.Splits ∧
          g.natDegree = f.natDegree ∧ (∀ t, 0 ≤ (wronskian g f).eval t) ∧
            ¬ StrictInterl g f

Lean source RealRooted/Challenges/Interlacing/Wronskian.lean at revision d6670742. Formalized 2026-10-06.