Second-order differential operators preserving PF polynomials

For $L=(a+bx)+(c+dx)\frac d{dx}+f\,x\frac{d^2}{dx^2}$ with $a,c,d\ge0$ and $b,f>0$, an explicit bound on $c$ decides whether $L$ maps every PF polynomial to a PF polynomial. Such operators generate polynomial sequences by $P_{n+1}=LP_n$, and PF preservation makes every member real-rooted.

Results

A polynomial is PF if it has nonnegative coefficients and is zero or has only real, nonpositive roots. For real $a,b,c,d,f$ let $$ L=(a+bx)+(c+dx)\,\frac{d}{dx}+f\,x\,\frac{d^2}{dx^2}, $$ and say $L$ preserves PF polynomials if $Lp$ is PF for every PF polynomial $p$. Put $\delta=d^2-4bf$ and, for $j\ge1$, $$ \tau_j=\begin{cases} a\bigl(d+\sqrt{\delta+4bf/j}\bigr)/(2b) & \text{if }a^2>j^2\delta+4bfj,\\ f+\dfrac{ad}{2b}+\dfrac{j\delta}{4b}+\dfrac{a^2}{4bj} & \text{if }\lvert j^2\delta-a^2\rvert\le4bfj,\\ \bigl(ad+\sqrt{\delta(a^2+4bfj)}\bigr)/(2b) & \text{otherwise.} \end{cases} $$

Theorem (classification). Let $a,c,d\ge0$, $b,f>0$ and $\delta>0$, and let $m\ge1$ satisfy $\delta m(m-1)\le a^2\le\delta m(m+1)$. Then $\tau_m\le\tau_j$ for all $j\ge1$, and $L$ preserves PF polynomials if and only if $c\le\tau_m$. In the middle case $\lvert m^2\delta-a^2\rvert\le4bfm$, the condition $c\le\tau_m$ reads $(a+dm)^2-4bm\bigl(c+f(m-1)\bigr)\ge0$.

Theorem (obstruction). If $b>0$ and $\delta<0$, then $L$ does not preserve PF polynomials.

Corollary (special cases). Write $D=d/dx$.

Theorem (orbits). Let $P_0=1$ and let $P_{n+1}$ be the image of $P_n$ under $p\mapsto xp''+\rho\,xp'+xp+\gamma p$. If $\rho,\gamma\ge0$ and $5\rho^2<8$, then $P_n$ has a nonreal root for all sufficiently large $n$.

Proof

The image $L(x^m)$ has a quadratic factor with discriminant $(a+dm)^2-4bm\bigl(c+f(m-1)\bigr)$, which is negative for some $m$ when $\delta<0$; the bound $\tau_j$ is the optimal condition on $c$ for the gap with $j$ roots to its right. For the orbit statement, the first two signed root moments (Newton sums) and the Cauchy–Schwarz inequality contradict the reality of all roots for large $n$.

References

Definitions

  • The operator (a + bX) + (c + dX) D + f X D²

    RealRooted.secondOrderRayOperatorsource
    def secondOrderRayOperator (a b c d f : ℝ) (p : ℝ[X]) : ℝ[X] :=
      (C a + C b * X) * p + (C c + C d * X) * p.derivative +
        C f * X * p.derivative.derivative
  • The operator maps every PF polynomial to a PF polynomial

    RealRooted.SecondOrderRayPreservingsource
    @[expose] def SecondOrderRayPreserving (a b c d f : ℝ) : Prop :=
      ∀ p : ℝ[X], IsPFPolynomial p →
        IsPFPolynomial (secondOrderRayOperator a b c d f p)
  • The optimized upper bound on c in the gap with j roots to its right

    RealRooted.secondOrderGapThresholdsource
    def secondOrderGapThreshold
        (a b d f delta : ℝ) (j : ℕ) : ℝ :=
      if a ^ 2 > (j : ℝ) ^ 2 * delta + 4 * b * f * j then
        a * (d + Real.sqrt (delta + 4 * b * f / j)) / (2 * b)
      else if |(j : ℝ) ^ 2 * delta - a ^ 2| ≤ 4 * b * f * j then
        f + a * d / (2 * b) + j * delta / (4 * b) +
          a ^ 2 / (4 * b * j)
      else
        (a * d + Real.sqrt (delta * (a ^ 2 + 4 * b * f * j))) / (2 * b)
  • The orbit of 1 under X D² + ρ X D + X + γ

    RealRooted.IsQuadraticDifferentialOrbitsource
    @[expose] def IsQuadraticDifferentialOrbit (P : ℕ → ℝ[X]) (ρ γ : ℝ) : Prop :=
      P 0 = 1 ∧ ∀ n, P (n + 1) = rhoGammaOperator ρ γ (P n)

Theorems

  • PF preservation is equivalent to an explicit bound on c in three regimesMain resultRealRooted original

    RealRooted.secondOrderRayPreserving_iff_three_branch_at_indexsource
    theorem secondOrderRayPreserving_iff_three_branch_at_index
        {a b c d f delta : ℝ} {m : ℕ}
        (ha : 0 ≤ a) (hb : 0 < b) (hc : 0 ≤ c) (hd : 0 ≤ d) (hf : 0 < f)
        (hdelta : 0 < delta) (hdisc : delta = d ^ 2 - 4 * b * f)
        (hm : 1 ≤ m)
        (hmlo : delta * (m : ℝ) * ((m : ℝ) - 1) ≤ a ^ 2)
        (hmhi : a ^ 2 ≤ delta * (m : ℝ) * ((m : ℝ) + 1)) :
        SecondOrderRayPreserving a b c d f ↔
          ((a ^ 2 > (m : ℝ) ^ 2 * delta + 4 * b * f * m ∧
            c ≤ a * (d + Real.sqrt (delta + 4 * b * f / m)) / (2 * b)) ∨
          (¬a ^ 2 > (m : ℝ) ^ 2 * delta + 4 * b * f * m ∧
            |(m : ℝ) ^ 2 * delta - a ^ 2| ≤ 4 * b * f * m ∧
            c ≤ f + a * d / (2 * b) + m * delta / (4 * b) +
              a ^ 2 / (4 * b * m)) ∨
          (¬a ^ 2 > (m : ℝ) ^ 2 * delta + 4 * b * f * m ∧
            ¬|(m : ℝ) ^ 2 * delta - a ^ 2| ≤ 4 * b * f * m ∧
            c ≤ (a * d + Real.sqrt
              (delta * (a ^ 2 + 4 * b * f * m))) / (2 * b)))
  • A negative residual discriminant d² - 4bf rules out PF preservationRealRooted original

    RealRooted.not_secondOrderRayPreserving_of_discrim_negsource
    theorem not_secondOrderRayPreserving_of_discrim_neg
        {a b c d f : ℝ} (hb : 0 < b) (hdelta : d ^ 2 - 4 * b * f < 0) :
        ¬SecondOrderRayPreserving a b c d f
  • Sufficiency: c below every gap threshold implies PF preservationRealRooted original

    RealRooted.secondOrderRayPreserving_of_forall_le_gapThresholdsource
    theorem secondOrderRayPreserving_of_forall_le_gapThreshold
        {a b c d f delta : ℝ}
        (ha : 0 ≤ a) (hb : 0 < b) (hc : 0 ≤ c) (hd : 0 ≤ d) (hf : 0 < f)
        (hdelta : 0 < delta) (hdisc : delta = d ^ 2 - 4 * b * f)
        (hthreshold : ∀ j, 1 ≤ j →
          c ≤ secondOrderGapThreshold a b d f delta j) :
        SecondOrderRayPreserving a b c d f
  • The lower regime: exact bound on c at the minimizing indexRealRooted original

    RealRooted.secondOrderRayPreserving_iff_lower_bound_at_indexsource
    theorem secondOrderRayPreserving_iff_lower_bound_at_index
        {a b c d f delta : ℝ} {m : ℕ}
        (ha : 0 ≤ a) (hb : 0 < b) (hc : 0 ≤ c) (hd : 0 ≤ d) (hf : 0 < f)
        (hdelta : 0 < delta) (hdisc : delta = d ^ 2 - 4 * b * f)
        (hm : 1 ≤ m)
        (hmlo : delta * (m : ℝ) * ((m : ℝ) - 1) ≤ a ^ 2)
        (hmhi : a ^ 2 ≤ delta * (m : ℝ) * ((m : ℝ) + 1))
        (hlower : (m : ℝ) ^ 2 * delta + 4 * b * f * m < a ^ 2) :
        SecondOrderRayPreserving a b c d f ↔
          c ≤ a * (d + Real.sqrt (delta + 4 * b * f / m)) / (2 * b)
  • The middle regime: preservation iff a discriminant is nonnegativeRealRooted original

    RealRooted.secondOrderRayPreserving_iff_middle_discrim_at_indexsource
    theorem secondOrderRayPreserving_iff_middle_discrim_at_index
        {a b c d f delta : ℝ} {m : ℕ}
        (ha : 0 ≤ a) (hb : 0 < b) (hc : 0 ≤ c) (hd : 0 ≤ d) (hf : 0 < f)
        (hdelta : 0 < delta) (hdisc : delta = d ^ 2 - 4 * b * f)
        (hm : 1 ≤ m)
        (hmlo : delta * (m : ℝ) * ((m : ℝ) - 1) ≤ a ^ 2)
        (hmhi : a ^ 2 ≤ delta * (m : ℝ) * ((m : ℝ) + 1))
        (hmiddle : |(m : ℝ) ^ 2 * delta - a ^ 2| ≤ 4 * b * f * m) :
        SecondOrderRayPreserving a b c d f ↔
          0 ≤ (a + d * m) ^ 2 - 4 * b * m * (c + f * (m - 1))
  • The upper regime: exact bound on c at the minimizing indexRealRooted original

    RealRooted.secondOrderRayPreserving_iff_upper_bound_at_indexsource
    theorem secondOrderRayPreserving_iff_upper_bound_at_index
        {a b c d f delta : ℝ} {m : ℕ}
        (ha : 0 ≤ a) (hb : 0 < b) (hc : 0 ≤ c) (hd : 0 ≤ d) (hf : 0 < f)
        (hdelta : 0 < delta) (hdisc : delta = d ^ 2 - 4 * b * f)
        (hm : 1 ≤ m)
        (hmlo : delta * (m : ℝ) * ((m : ℝ) - 1) ≤ a ^ 2)
        (hmhi : a ^ 2 ≤ delta * (m : ℝ) * ((m : ℝ) + 1))
        (hupperBranch : a ^ 2 + 4 * b * f * m < (m : ℝ) ^ 2 * delta) :
        SecondOrderRayPreserving a b c d f ↔
          c ≤ (a * d + Real.sqrt
            (delta * (a ^ 2 + 4 * b * f * m))) / (2 * b)
  • The gap threshold is minimized at the index m with δm(m-1) ≤ a² ≤ δm(m+1)RealRooted original

    RealRooted.secondOrderGapThreshold_minimized_at_indexsource
    theorem secondOrderGapThreshold_minimized_at_index
        {a b d f delta : ℝ} {m j : ℕ}
        (ha : 0 ≤ a) (hb : 0 < b) (hf : 0 < f) (hdelta : 0 < delta)
        (hm : 1 ≤ m) (hj : 1 ≤ j)
        (hmlo : delta * (m : ℝ) * ((m : ℝ) - 1) ≤ a ^ 2)
        (hmhi : a ^ 2 ≤ delta * (m : ℝ) * ((m : ℝ) + 1)) :
        secondOrderGapThreshold a b d f delta m ≤
          secondOrderGapThreshold a b d f delta j
  • With c = 0 and 4bf ≤ d², the operator preserves PF polynomialsRealRooted original

    RealRooted.IsPFPolynomial.secondOrderRayOperator_of_constDerivative_eq_zerosource
    theorem IsPFPolynomial.secondOrderRayOperator_of_constDerivative_eq_zero
        {p : ℝ[X]} (hp : IsPFPolynomial p) {a b d f : ℝ}
        (ha : 0 ≤ a) (hb : 0 < b) (hd : 0 ≤ d) (hf : 0 < f)
        (hdelta : 4 * b * f ≤ d ^ 2) :
        IsPFPolynomial (secondOrderRayOperator a b 0 d f p)
  • X (D + b)(D + a) + c preserves PF polynomials for a, b > 0 and c ≥ 0RealRooted original

    RealRooted.IsPFPolynomial.quadraticPFOperator_of_possource
    theorem IsPFPolynomial.quadraticPFOperator_of_pos {p : ℝ[X]}
        (hp : IsPFPolynomial p) {a b c : ℝ}
        (ha : 0 < a) (hb : 0 < b) (hc : 0 ≤ c) :
        IsPFPolynomial (quadraticPFOperator a b c p)
  • X (A D² + B D + C) + E preserves PF polynomials when 4AC ≤ B²RealRooted original

    RealRooted.IsPFPolynomial.secondOrderPFOperator_of_discrim_nonnegsource
    theorem IsPFPolynomial.secondOrderPFOperator_of_discrim_nonneg
        {p : ℝ[X]} (hp : IsPFPolynomial p) {A B C₀ E : ℝ}
        (hA : 0 < A) (hC : 0 < C₀) (hB : 0 ≤ B) (hE : 0 ≤ E)
        (hdisc : 4 * A * C₀ ≤ B ^ 2) :
        IsPFPolynomial (secondOrderPFOperator A B C₀ E p)
  • X D² + ρ X D + X + γ preserves PF polynomials for ρ ≥ 2 and γ ≥ 0RealRooted original

    RealRooted.IsPFPolynomial.rhoGammaOperator_of_two_lesource
    theorem IsPFPolynomial.rhoGammaOperator_of_two_le {p : ℝ[X]}
        (hp : IsPFPolynomial p) {rho gamma : ℝ} (hrho : 2 ≤ rho)
        (hgamma : 0 ≤ gamma) : IsPFPolynomial (rhoGammaOperator rho gamma p)
  • Counterexample: the operator with ρ = 0, γ = 1 does not preserve PF polynomialsRealRooted original

    RealRooted.rhoGammaOperator_zero_one_counterexamplesource
    theorem rhoGammaOperator_zero_one_counterexample :
        IsPFPolynomial ((X + 1 : ℝ[X]) ^ 2) ∧
          ¬IsPFPolynomial
            (rhoGammaOperator 0 1 ((X + 1 : ℝ[X]) ^ 2))
  • For 5ρ² < 8 the orbit has non-real roots in all large ranksRealRooted original

    RealRooted.IsQuadraticDifferentialOrbit.exists_forall_exists_nonreal_rootsource
    theorem IsQuadraticDifferentialOrbit.exists_forall_exists_nonreal_root
        {P : ℕ → ℝ[X]} {ρ γ : ℝ} (hP : IsQuadraticDifferentialOrbit P ρ γ)
        (hρ : 0 ≤ ρ) (hγ : 0 ≤ γ) (hsmall : 5 * ρ ^ 2 < 8) :
        ∃ N : ℕ, ∀ n, N ≤ n →
          ∃ z : ℂ, ((P n).map Complex.ofRealHom).eval z = 0 ∧ z.im ≠ 0

Lean source RealRooted/Challenges/Preservers/SecondOrderRayOperators.lean at revision d6670742. Formalized 2026-11-01.