Borcea–Brändén classification of stability preservers

A linear operator on polynomials in finitely many variables preserves stability if and only if it has rank at most one (two, in the real case) with a stable range, or its symbol is stable or a limit of stable polynomials. Stable symbols give concrete preservers: univariate real-rootedness preservers, coordinate multipliers and differential operators.

Results

A polynomial in $z=(z_i)_{i\in\sigma}$, with $\sigma$ finite, is stable if it has no zero with every $z_i$ in the open upper half-plane; real stable means stable with real coefficients. An operator preserves (real) stability if it maps (real) stable polynomials to (real) stable polynomials or to zero. For a linear operator $T$, the algebraic symbol on the degree box $\kappa\in\mathbb N^\sigma$ is $T\bigl[\prod_i(z_i+w_i)^{\kappa_i}\bigr]$, and the transcendental symbol is the series $$ T\bigl[e^{-z\cdot w}\bigr]=\sum_\alpha(-1)^{|\alpha|}\,T(z^\alpha)\,\frac{w^\alpha}{\alpha!}, $$ with $T$ acting on $z$. Theorem numbers refer to [BB09].

Theorem (Borcea–Brändén). Let $T$ be a linear operator on polynomials in $z$.

  1. (Theorem 1.1) A complex-linear $T$ on the polynomials of degree at most $\kappa_i$ in each $z_i$ preserves stability if and only if $Tf=\varphi(f)P$ for a linear functional $\varphi$ and a stable $P$, or its algebraic symbol is stable.
  2. (Theorem 1.2) A real-linear $T$ on this degree box preserves real stability if and only if $Tf=\varphi(f)P+\psi(f)Q$, where every real linear combination of $P$ and $Q$ is real stable or zero, or one of $T\bigl[\prod_i(z_i+w_i)^{\kappa_i}\bigr]$ and $T\bigl[\prod_i(z_i-w_i)^{\kappa_i}\bigr]$ is real stable.
  3. (Theorem 1.3) A complex-linear $T$ on all polynomials preserves stability if and only if it has the rank-one form above, or its transcendental symbol is a locally uniform limit of stable polynomials.
  4. (Theorem 1.4) A real-linear $T$ on all polynomials preserves real stability if and only if it has the rank-two form above, or its transcendental symbol or the same series with $w$ replaced by $-w$ is a locally uniform limit of real stable polynomials.

Theorem 5.1. A series $\sum_\alpha P_\alpha(z)\,w^\alpha$ is a locally uniform limit of stable polynomials if and only if every truncation $\sum_{\alpha\le\beta}\prod_i\binom{\beta_i}{\alpha_i}\alpha_i!\,P_\alpha(z)\,w^\alpha$ is stable or zero. The same holds with real stable polynomials.

Corollaries.

Proof

The coordinate multipliers come from the finite-degree theorem in one variable, and the differential operators from the falling-factorial multiplier together with the finite-degree theorem on each degree box. Theorem 5.1 follows by induction on the number of variables in the support and on its minimal total degree, using specialization and partial differentiation. This replaces a step in the proof of [BB09, Theorem 5.6], which assumes that partial differentiation lowers the largest degree among the minimal exponents of the support by one; that fails for a general support.

References

  1. [BB09] Julius Borcea & Petter Brändén. The Lee–Yang and Pólya–Schur programs. I. Linear operators preserving stability. Inventiones mathematicae, 177(3), 541-569, 2009.
    BibTeX
    @article{BorceaBranden2009I,
      doi = {10.1007/s00222-009-0189-3},
      url2 = {https://doi.org/10.1007/s00222-009-0189-3},
      year = {2009},
      month = mar,
      publisher = {Springer Science and Business Media {LLC}},
      volume = {177},
      number = {3},
      pages = {541--569},
      author = {Julius Borcea and Petter Br{\"{a}}nd{\'{e}}n},
      title = {The {L}ee--{Y}ang and {P}{\'{o}}lya--{S}chur programs. {I}. {L}inear operators preserving stability},
      journal = {Inventiones mathematicae}
    }

Definitions

  • Stability preserver on a degree box

    RealRooted.BorceaBranden.PreservesComplexStabilityOnDegreeBoxsource
    def PreservesComplexStabilityOnDegreeBox
        {σ : Type*} (κ : σ → ℕ)
        (T : MvPolynomial.degreeOfLE σ ℂ κ →ₗ[ℂ] MvPolynomial σ ℂ) : Prop :=
      ∀ f, MvUpperHalfPlaneStable f.1 →
        MvUpperHalfPlaneStableOrZero (T f)
  • Rank-one operator with stable image

    RealRooted.BorceaBranden.HasStableRankOneRepresentationsource
    def HasStableRankOneRepresentation
        {σ : Type*} (κ : σ → ℕ)
        (T : MvPolynomial.degreeOfLE σ ℂ κ →ₗ[ℂ] MvPolynomial σ ℂ) : Prop :=
      ∃ (α : MvPolynomial.degreeOfLE σ ℂ κ →ₗ[ℂ] ℂ)
          (P : MvPolynomial σ ℂ),
        MvUpperHalfPlaneStable P ∧ ∀ f, T f = (α f) • P
  • Real stability preserver on a degree box

    RealRooted.BorceaBranden.PreservesRealStabilityOnDegreeBoxsource
    def PreservesRealStabilityOnDegreeBox
        {σ : Type*} (κ : σ → ℕ)
        (T : MvPolynomial.degreeOfLE σ ℝ κ →ₗ[ℝ] MvPolynomial σ ℝ) : Prop :=
      ∀ f, MvRealStable f.1 → MvRealStableOrZero (T f)
  • Stable rank-at-most-two degree-box representation

    RealRooted.BorceaBranden.HasStableRankTwoRepresentationsource
    def HasStableRankTwoRepresentation
        {σ : Type*} (κ : σ → ℕ)
        (T : MvPolynomial.degreeOfLE σ ℝ κ →ₗ[ℝ] MvPolynomial σ ℝ) : Prop :=
      ∃ (α β : MvPolynomial.degreeOfLE σ ℝ κ →ₗ[ℝ] ℝ)
          (P Q : MvPolynomial σ ℝ),
        AllComboMvRealStableOrZero P Q ∧
          ∀ f, T f = (α f) • P + (β f) • Q
  • Complex stability preserver

    RealRooted.BorceaBranden.PreservesComplexStabilitysource
    def PreservesComplexStability
        (T : MvPolynomial σ ℂ →ₗ[ℂ] MvPolynomial σ ℂ) : Prop :=
      ∀ p, MvUpperHalfPlaneStable p → MvUpperHalfPlaneStableOrZero (T p)
  • Stable rank-at-most-one representation

    RealRooted.BorceaBranden.HasGlobalStableRankOneRepresentationsource
    def HasGlobalStableRankOneRepresentation
        (T : MvPolynomial σ ℂ →ₗ[ℂ] MvPolynomial σ ℂ) : Prop :=
      ∃ (α : MvPolynomial σ ℂ →ₗ[ℂ] ℂ) (P : MvPolynomial σ ℂ),
        MvUpperHalfPlaneStable P ∧ ∀ p, T p = (α p) • P
    
    omit [Fintype σ] in
  • Real stability preserver

    RealRooted.BorceaBranden.PreservesRealStabilitysource
    def PreservesRealStability
        (T : MvPolynomial σ ℝ →ₗ[ℝ] MvPolynomial σ ℝ) : Prop :=
      ∀ p, MvRealStable p → MvRealStableOrZero (T p)
  • Stable rank-at-most-two representation

    RealRooted.BorceaBranden.HasGlobalStableRankTwoRepresentationsource
    def HasGlobalStableRankTwoRepresentation
        (T : MvPolynomial σ ℝ →ₗ[ℝ] MvPolynomial σ ℝ) : Prop :=
      HasStableRankTwoRangeRepresentation T
    
    omit [Fintype σ] in
  • Complex stable-limit class

    RealRooted.BorceaBranden.IsComplexStableLimitsource
    def IsComplexStableLimit (P : (σ →₀ ℕ) → MvPolynomial τ ℂ) : Prop :=
      ∃ F : ℕ → MvPolynomial (τ ⊕ σ) ℂ,
        (∀ k, MvUpperHalfPlaneStableOrZero (F k)) ∧
        (∀ x : τ ⊕ σ → ℂ,
          Summable fun e : τ ⊕ σ →₀ ℕ => ‖seriesCoeff P e * ∏ i, x i ^ e i‖) ∧
        TendstoLocallyUniformly (fun k (x : τ ⊕ σ → ℂ) => MvPolynomial.eval x (F k))
          (fun x => ∑' e : τ ⊕ σ →₀ ℕ, seriesCoeff P e * ∏ i, x i ^ e i) atTop
  • Real stable-limit class

    RealRooted.BorceaBranden.IsRealStableLimitsource
    def IsRealStableLimit (P : (σ →₀ ℕ) → MvPolynomial τ ℝ) : Prop :=
      ∃ F : ℕ → MvPolynomial (τ ⊕ σ) ℝ,
        (∀ k, MvRealStable (F k)) ∧
        (∀ x : τ ⊕ σ → ℂ,
          Summable fun e : τ ⊕ σ →₀ ℕ =>
            ‖(realSeriesCoeff P e : ℂ) * ∏ i, x i ^ e i‖) ∧
        TendstoLocallyUniformly
          (fun k (x : τ ⊕ σ → ℂ) =>
            MvPolynomial.eval x (MvPolynomial.map Complex.ofRealHom (F k)))
          (fun x => ∑' e : τ ⊕ σ →₀ ℕ,
            (realSeriesCoeff P e : ℂ) * ∏ i, x i ^ e i) atTop
  • Complex transcendental-symbol coefficient family

    RealRooted.BorceaBranden.transcendentalSymbolPolynomialsource
    def transcendentalSymbolPolynomial
        (T : MvPolynomial σ ℂ →ₗ[ℂ] MvPolynomial τ ℂ) (α : σ →₀ ℕ) :
        MvPolynomial τ ℂ :=
      MvPolynomial.C (signedInvFactorial α) * T (MvPolynomial.monomial α 1)
  • Real transcendental-symbol coefficient family

    RealRooted.BorceaBranden.realTranscendentalSymbolPolynomialsource
    def realTranscendentalSymbolPolynomial
        (T : MvPolynomial σ ℝ →ₗ[ℝ] MvPolynomial τ ℝ)
        (α : σ →₀ ℕ) : MvPolynomial τ ℝ :=
      MvPolynomial.C (realSignedInvFactorial α) *
        T (MvPolynomial.monomial α 1)
  • Right-sign reversal of a coefficient family

    RealRooted.BorceaBranden.negRightFamilysource
    def negRightFamily (P : (σ →₀ ℕ) → MvPolynomial τ ℝ)
        (α : σ →₀ ℕ) : MvPolynomial τ ℝ :=
      MvPolynomial.C ((-1 : ℝ) ^ (∑ i, α i)) * P α
  • Algebraic symbol of an operator

    RealRooted.BorceaBranden.finiteAlgebraicSymbolsource
    def finiteAlgebraicSymbol (d : ℕ) (T : ℝ[X] →ₗ[ℝ] ℝ[X]) :
        MvPolynomial (Fin 2) ℝ :=
      ∑ k ∈ Finset.range (d + 1),
        MvPolynomial.C (Nat.choose d k : ℝ) *
          polynomialInFirstMv (T ((X : ℝ[X]) ^ k)) *
            (MvPolynomial.X (1 : Fin 2)) ^ (d - k)
  • Real-rootedness preserver up to degree d

    RealRooted.BorceaBranden.PreservesRealRootedUpTosource
    def PreservesRealRootedUpTo
        (d : ℕ) (T : ℝ[X] →ₗ[ℝ] ℝ[X]) : Prop :=
      ∀ {p : ℝ[X]}, p.natDegree ≤ d → p.Splits → T p = 0 ∨ (T p).Splits
    
    end

Theorems

  • Complex finite-degree classification (Theorem 1.1)

    RealRooted.BorceaBranden.finiteComplexSymbolClassificationsource
    theorem finiteComplexSymbolClassification :
        ∀ (σ : Type) [Fintype σ] (κ : σ → ℕ)
            (T : MvPolynomial.degreeOfLE σ ℂ κ →ₗ[ℂ] MvPolynomial σ ℂ),
          PreservesComplexStabilityOnDegreeBox κ T ↔
            HasStableRankOneRepresentation κ T ∨
              MvUpperHalfPlaneStable (MvPolynomial.algebraicSymbol κ T)
  • Real finite-degree classification (Theorem 1.2)

    RealRooted.BorceaBranden.realStabilityOnDegreeBox_iff_rankTwo_or_stable_symbolsourcestatement on symmetricfunctions.com
    theorem realStabilityOnDegreeBox_iff_rankTwo_or_stable_symbol
        {σ : Type*} [Fintype σ] (κ : σ → ℕ)
        (T : MvPolynomial.degreeOfLE σ ℝ κ →ₗ[ℝ] MvPolynomial σ ℝ) :
        PreservesRealStabilityOnDegreeBox κ T ↔
          HasStableRankTwoRepresentation κ T ∨
            MvRealStable (MvPolynomial.algebraicSymbol κ T) ∨
            MvRealStable (MvPolynomial.algebraicSymbolNegRight κ T)
  • Complex classification (Theorem 1.3)

    RealRooted.BorceaBranden.complexStability_iff_rankOne_or_stableLimit_symbolsource
    theorem complexStability_iff_rankOne_or_stableLimit_symbol
        (T : MvPolynomial σ ℂ →ₗ[ℂ] MvPolynomial σ ℂ) :
        PreservesComplexStability T ↔
          HasGlobalStableRankOneRepresentation T ∨
            IsComplexStableLimit (transcendentalSymbolPolynomial T)
  • Real classification (Theorem 1.4)Main result

    RealRooted.BorceaBranden.realStability_iff_rankTwo_or_stableLimit_signedSymbolsourcestatement on symmetricfunctions.com
    theorem realStability_iff_rankTwo_or_stableLimit_signedSymbol
        (T : MvPolynomial σ ℝ →ₗ[ℝ] MvPolynomial σ ℝ) :
        PreservesRealStability T ↔
          HasGlobalStableRankTwoRepresentation T ∨
            IsRealStableLimit (realTranscendentalSymbolPolynomial T) ∨
            IsRealStableLimit
              (negRightFamily (realTranscendentalSymbolPolynomial T))
  • Complex stable-limit criterion (Theorem 5.1)

    RealRooted.BorceaBranden.isComplexStableLimit_iff_fallingFactorial_glue_stablesource
    theorem isComplexStableLimit_iff_fallingFactorial_glue_stable
        (P : (σ →₀ ℕ) → MvPolynomial τ ℂ) :
        IsComplexStableLimit P ↔
          ∀ β : σ →₀ ℕ,
            MvUpperHalfPlaneStableOrZero (glue P (fun α => fall α β) β)
  • Real stable-limit criterion (Theorem 5.1)

    RealRooted.BorceaBranden.isRealStableLimit_iff_forall_realGlue_stableOrZerosource
    theorem isRealStableLimit_iff_forall_realGlue_stableOrZero
        (P : (σ →₀ ℕ) → MvPolynomial τ ℝ) :
        IsRealStableLimit P ↔
          ∀ β : σ →₀ ℕ,
            MvRealStableOrZero (realGlue P (fun α => fall α β) β)
  • A real stable symbol T((x + y)^d) gives a real-rootedness preserver up to degree d

    RealRooted.BorceaBranden.PreservesRealRootedUpTo.of_finiteSymbolsource
    theorem PreservesRealRootedUpTo.of_finiteSymbol
        {d : ℕ} {T : ℝ[X] →ₗ[ℝ] ℝ[X]}
        (hSymbol : MvUpperHalfPlaneStable
          (complexifyMv
            (RealRooted.BorceaBranden.finiteAlgebraicSymbol d T))) :
        RealRooted.BorceaBranden.PreservesRealRootedUpTo d T
  • Coordinate PF multipliers preserve multivariate stability

    RealRooted.MvUpperHalfPlaneStable.coordinateDiagonalOperatorsource
    theorem _root_.RealRooted.MvUpperHalfPlaneStable.coordinateDiagonalOperator
        {σ : Type*} [Finite σ] (d : ℕ) (gamma : ℕ → ℝ) (q : σ)
        (hJ : IsPFPolynomial (jensenPolynomial d gamma))
        {p : _root_.MvPolynomial σ ℂ} (hpq : p.degreeOf q ≤ d)
        (hp : MvUpperHalfPlaneStable p) :
        MvUpperHalfPlaneStableOrZero (coordinateDiagonalOperator gamma q p)
  • A stable signed Weyl symbol gives a stability preserver of any degree

    RealRooted.MvUpperHalfPlaneStable.finiteOrderWeylOperatorsource
    theorem _root_.RealRooted.MvUpperHalfPlaneStable.finiteOrderWeylOperator
        {σ : Type*} [Finite σ] (q : σ) (m : ℕ)
        (Q : Fin (m + 1) → MvPolynomial σ ℂ)
        (hW : MvUpperHalfPlaneStable (signedWeylSymbol m Q))
        {p : MvPolynomial σ ℂ} (hp : MvUpperHalfPlaneStable p) :
        MvUpperHalfPlaneStableOrZero (finiteOrderWeylOperator q m Q p)
  • The Poisson star product is associative

    RealRooted.Poisson.star_assocsource
    theorem star_assoc {R : Type*} [CommRing R]
        (f g h : MvPolynomial Bool R) :
        star (star f g) h = star f (star g h)
  • Poisson left multiplication preserves real stability

    RealRooted.Poisson.spectatorAction_stablesource
    theorem spectatorAction_stable {τ : Type*} [Finite τ]
        {f : MvPolynomial Bool ℝ} (hf : MvRealStable f)
        (hfnn : f.HasNonnegCoeffs) {P : MvPolynomial (Bool ⊕ τ) ℝ}
        (hP : MvRealStable P) :
        MvRealStable (spectatorAction f P)

Lean source RealRooted/Challenges/Stability/BorceaBrandenClassification.lean at revision d6670742. Formalized 2026-10-13.