Basis transforms preserving real-rootedness and PF

A basis transform sends $x^n$ to a fixed polynomial $B_n$. For Newton bases, for bases defined by order-two recurrences, and for the semigroup generated by $aD+bxD^2$, we determine exactly when the transform preserves real-rootedness or the Pólya frequency property. In each case a short list of parameter inequalities decides.

Results

For $B_n\in\mathbb R[x]$ let $T_B$ be the linear map with $T_B(x^n)=B_n$, that is, $T_B\bigl(\sum_n a_nx^n\bigr)=\sum_n a_nB_n$. A polynomial is PF (Pólya frequency) if it is zero or has nonnegative coefficients and only real, nonpositive roots. On this page a real-rooted polynomial may be zero.

Theorem (Newton bases). For $c=(c_j)_{j\ge0}$ let $N_n^{c}(x)=\prod_{j=0}^{n-1}(x+c_j)$ and $T_c(x^n)=N_n^{c}$. The following are equivalent:

  1. $T_c$ maps every real-rooted polynomial with only nonpositive roots to a real-rooted polynomial;
  2. $T_c\bigl((x+r)^n\bigr)$ is real-rooted for all $n\ge0$ and $r\ge0$;
  3. $c_j=c_0+jh$ for all $j$, for some $h\ge0$.

For $N\ge2$ the same equivalences hold for inputs of degree at most $N$, with the tests restricted to $n\le N$ and the progression condition to $j<N$.

Theorem (order-two bases). Let $a\ge0$, $b>0$, $s\ge0$ and $c\in\mathbb R$. Put $B_0=1$, $B_1=s$ and $B_{n+2}=a\,B_{n+1}+(bx+c)\,B_n$. The following are equivalent:

  1. $T_B$ maps every PF polynomial to a PF polynomial;
  2. every $B_n$ is PF;
  3. $B_n(0)\ge0$ for all $n$;
  4. $a^2+4c\ge0$ and ($2s\ge a$ or $c\ge s^2-as$).

The same criterion characterizes the maps that send PF polynomials with roots in $[-R,0]$ to PF polynomials, for any fixed $R\ge0$. No degree bound suffices: for every $N$ there is $c<-\tfrac14$ such that, for $a=b=s=1$, $T_B$ maps PF polynomials of degree at most $N$ to PF polynomials but not every PF polynomial.

Theorem (ray semigroup). For $a,b,t\in\mathbb R$ let $T_t$ be the linear map with $T_t(x^n)=B_n(t)$, where $B_0=1$ and $$ B_{n+1}=\bigl(x+t(a+bn)\bigr)B_n+bt\,x\,B_n'. $$ Then $T_0=\mathrm{id}$ and $T_{s+t}=T_sT_t$, and $T_t$ maps PF polynomials to PF polynomials for every $t\ge0$ if and only if $a\ge0$ and $b\ge0$. The two parameters are read off from the truncated logarithm $\ell=(T_1-1)-\tfrac12(T_1-1)^2$ as $a=[x^0]\,\ell(x)$ and $b=\tfrac12[x^1]\,\ell(x^2)-[x^0]\,\ell(x)$.

The other results are as follows.

Use

The Newton and order-two classifications reduce preservation to tests on repeated roots and constant terms. The multiplier sequences page treats the classical diagonal preservers, and the Narayana polynomials page uses rising and falling factorial bases.

References

Definitions

  • The Newton basis polynomial with parameters c

    RealRooted.newtonBasisPolynomialsource
    def newtonBasisPolynomial (c : ℕ → ℝ) (n : ℕ) : ℝ[X] :=
      ∏ j ∈ Finset.range n, (X + C (c j))
  • The basis generated by an order-two recurrence

    RealRooted.orderTwoBasissource
    def orderTwoBasis (a b c s : ℝ) : ℕ → ℝ[X]
      | 0 => 1
      | 1 => C s
      | n + 2 => C a * orderTwoBasis a b c s (n + 1) +
          (C b * X + C c) * orderTwoBasis a b c s n
  • The ray semigroup generated by aD + bXD²

    RealRooted.raySemigroupTransformsource
    def raySemigroupTransform (a b t : ℝ) (p : ℝ[X]) : ℝ[X] :=
      basisTransform (raySemigroupBasis a b t) p
  • The differential (Appell) coefficients of a basis

    RealRooted.appellCoefficientsource
    def appellCoefficient (P : ℕ → ℝ[X]) (k : ℕ) : ℝ[X] :=
      C ((k.factorial : ℝ)⁻¹) *
        ∑ j ∈ range (k + 1),
          C (k.choose j : ℝ) * ((-X) ^ (k - j) * P j)
  • Nonzero, real-rooted, with all roots in a set

    RealRooted.IsRealRootedInsource
    def IsRealRootedIn (S : Set ℝ) (p : ℝ[X]) : Prop :=
      p ≠ 0 ∧ p.Splits ∧ ∀ r ∈ p.roots, r ∈ S
  • The basis map generated by an interval differential operator

    RealRooted.intervalBasisMapsource
    @[expose] def intervalBasisMap
        (alpha beta rho kappa L U : ℝ) (g p : ℝ[X]) : ℝ[X] :=
      basisTransform
        (fun n ↦ (intervalDifferentialOperator alpha beta rho kappa L U ^ n) g) p
  • The monomial images of the ray semigroup

    RealRooted.raySemigroupBasissource
    def raySemigroupBasis (a b t : ℝ) : ℕ → ℝ[X]
      | 0 => 1
      | n + 1 =>
          (X + C (t * (a + b * n))) * raySemigroupBasis a b t n +
            C (b * t) * X * (raySemigroupBasis a b t n).derivative
  • Translation and Lah generators

    RealRooted.TranslationLahGeneratorsource
    inductive TranslationLahGenerator where
      /-- Translation by the displayed amount. -/
      | translation (a : ℝ)
      /-- Lah flow for the displayed time. -/
      | lah (b : ℝ)
      deriving DecidableEq
  • Rows with a translation–Lah exponential generating function

    RealRooted.HasTranslationLahEGFsource
    def HasTranslationLahEGF
        (P : ℕ → ℝ[X]) (β : ℝ) (atoms : List (ℝ × ℝ)) : Prop :=
      polynomialRowEGF P =
        (translationLahPrefactorSeries atoms).map C *
          (PowerSeries.exp ℝ[X]).subst
            (PowerSeries.C X * (translationLahSubstitutionSeries β).map C)
  • Discrepancy of a prefix row from the geometric tail

    RealRooted.geometricDiscrepancysource
    def geometricDiscrepancy (P : ℕ → ℝ[X]) (y : ℝ[X]) (k j : ℕ) : ℝ[X] :=
      y ^ k * P j - P k * y ^ j
  • The linear map sending X^n to L^n g

    RealRooted.polynomialOrbitMapsource
    def polynomialOrbitMap (L : Module.End ℝ V) (g : V) : ℝ[X] →ₗ[ℝ] V :=
      Polynomial.lsum fun n ↦
        LinearMap.toSpanSingleton ℝ V ((L ^ n) g)

Theorems

  • Newton basis preserves real-rootedness exactly when c is a nondecreasing progressionMain resultRealRooted original

    RealRooted.newtonBasis_preserver_equivalencessource
    theorem newtonBasis_preserver_equivalences (c : ℕ → ℝ) :
        (NewtonPreservesNonposRooted c ↔ NewtonRepeatedRootTests c) ∧
          (NewtonRepeatedRootTests c ↔ NewtonParametersAffine c)
  • The degree-N version of the Newton-basis classificationRealRooted original

    RealRooted.newtonBasis_preserver_equivalencesUpTosource
    theorem newtonBasis_preserver_equivalencesUpTo
        {N : ℕ} (hN : 2 ≤ N) (c : ℕ → ℝ) :
        (NewtonPreservesNonposRootedUpTo N c ↔ NewtonRepeatedRootTestsUpTo N c) ∧
          (NewtonRepeatedRootTestsUpTo N c ↔ NewtonParametersAffineUpTo N c)
  • PF preservation for an order-two basis: four equivalent conditionsRealRooted original

    RealRooted.orderTwoBasis_pf_equivalencessource
    theorem orderTwoBasis_pf_equivalences
        {a b c s : ℝ} (ha : 0 ≤ a) (hb : 0 < b) (hs : 0 ≤ s) :
        ((∀ p : ℝ[X], IsPFPolynomial p →
              IsPFPolynomial (basisTransform (orderTwoBasis a b c s) p)) ↔
            ∀ n, IsPFPolynomial (orderTwoBasis a b c s n)) ∧
          ((∀ n, IsPFPolynomial (orderTwoBasis a b c s n)) ↔
            ∀ n, 0 ≤ (orderTwoBasis a b c s n).eval 0) ∧
          ((∀ n, 0 ≤ (orderTwoBasis a b c s n).eval 0) ↔
            0 ≤ a ^ 2 + 4 * c ∧ (2 * s ≥ a ∨ c ≥ s ^ 2 - a * s))
  • Bounded-root PF inputs already detect the order-two criterionRealRooted original

    RealRooted.basisTransform_orderTwoBasis_preserves_bounded_pf_iffsource
    theorem basisTransform_orderTwoBasis_preserves_bounded_pf_iff
        {a b c s R : ℝ} (ha : 0 ≤ a) (hb : 0 < b) (hs : 0 ≤ s) (hR : 0 ≤ R) :
        (∀ p : ℝ[X], IsPFPolynomial p →
            (∀ r ∈ p.roots, -R ≤ r ∧ r ≤ 0) →
            IsPFPolynomial (basisTransform (orderTwoBasis a b c s) p)) ↔
          0 ≤ a ^ 2 + 4 * c ∧ (2 * s ≥ a ∨ c ≥ s ^ 2 - a * s)
  • No degree cap detects PF preservation for order-two basesRealRooted original

    RealRooted.exists_orderTwoBasis_finite_cap_counterexamplesource
    theorem exists_orderTwoBasis_finite_cap_counterexample (N : ℕ) :
        ∃ c : ℝ, c < -(1 / 4 : ℝ) ∧
          (∀ p : ℝ[X], IsPFPolynomial p → p.natDegree ≤ N →
            IsPFPolynomial (basisTransform (orderTwoBasis 1 1 c 1) p)) ∧
          ¬(∀ p : ℝ[X], IsPFPolynomial p →
            IsPFPolynomial (basisTransform (orderTwoBasis 1 1 c 1) p))
  • The ray semigroup preserves PF polynomials exactly when a, b ≥ 0RealRooted original

    RealRooted.raySemigroupTransform_preservesPF_iffsource
    theorem raySemigroupTransform_preservesPF_iff (a b : ℝ) :
        (∀ t, 0 ≤ t → ∀ {p : ℝ[X]}, IsPFPolynomial p →
          IsPFPolynomial (raySemigroupTransform a b t p)) ↔
          0 ≤ a ∧ 0 ≤ b
  • The semigroup law T_{s+t} = T_s T_tRealRooted original

    RealRooted.raySemigroupTransform_add_timesource
    theorem raySemigroupTransform_add_time (a b s t : ℝ) (p : ℝ[X]) :
        raySemigroupTransform a b (s + t) p =
          raySemigroupTransform a b s (raySemigroupTransform a b t p)
  • The degree-two finite logarithm detects PF preservation of the semigroupRealRooted original

    RealRooted.raySemigroupTransform_preservesPF_iff_finiteLogsource
    theorem raySemigroupTransform_preservesPF_iff_finiteLog (a b : ℝ) :
        (∀ t, 0 ≤ t → ∀ {p : ℝ[X]}, IsPFPolynomial p →
          IsPFPolynomial (raySemigroupTransform a b t p)) ↔
          0 ≤ (finiteEndomorphismLog 2 (raySemigroupEnd a b 1) X).coeff 0 ∧
            0 ≤ (finiteEndomorphismLog 2
                (raySemigroupEnd a b 1) (X ^ 2)).coeff 1 / 2 -
              (finiteEndomorphismLog 2 (raySemigroupEnd a b 1) X).coeff 0
  • Appell coefficients: β = 0 iff all constant, translation-commuting, Appell basisRealRooted original

    RealRooted.appellTranslationRigidity_equivalencessource
    theorem appellTranslationRigidity_equivalences
        {P : ℕ → ℝ[X]} (hPdeg : ∀ n, (P n).natDegree = n)
        (hPmonic : ∀ n, (P n).Monic)
        (hpres : ∀ p : ℝ[X], p.Splits →
          (∀ r ∈ p.roots, r ≤ 0) → (basisTransform P p).Splits) :
        let beta
  • With vanishing quadratic coefficient, every real-rooted input is preservedRealRooted original

    RealRooted.basisTransform_splits_of_quadraticCoefficient_eq_zerosource
    theorem basisTransform_splits_of_quadraticCoefficient_eq_zero
        {P : ℕ → ℝ[X]} (hPdeg : ∀ n, (P n).natDegree = n)
        (hPmonic : ∀ n, (P n).Monic)
        (hpres : ∀ p : ℝ[X], p.Splits →
          (∀ r ∈ p.roots, r ≤ 0) → (basisTransform P p).Splits)
        (hbeta : 2 * (appellCoefficient P 2).coeff 1 = 0)
        {p : ℝ[X]} (hp : p.Splits) :
        (basisTransform P p).Splits
  • Appell coefficients of a root-preserving monic basis have degree at most k/2RealRooted original

    RealRooted.appellCoefficient_natDegree_lesource
    theorem appellCoefficient_natDegree_le
        {P : ℕ → ℝ[X]} (hPdeg : ∀ n, (P n).natDegree = n)
        (hPmonic : ∀ n, (P n).Monic)
        (hpres : ∀ p : ℝ[X], p.Splits →
          (∀ r ∈ p.roots, r ≤ 0) → (basisTransform P p).Splits) (k : ℕ) :
        (appellCoefficient P k).natDegree ≤ k / 2
  • Bounds 0 ≤ [x^j]A_{2j} ≤ ([x^1]A_2)^j/j! for the even Appell coefficientsRealRooted original

    RealRooted.coeff_appellCoefficient_even_boundssource
    theorem coeff_appellCoefficient_even_bounds
        {P : ℕ → ℝ[X]} (hPdeg : ∀ n, (P n).natDegree = n)
        (hPmonic : ∀ n, (P n).Monic)
        (hpres : ∀ p : ℝ[X], p.Splits →
          (∀ r ∈ p.roots, r ≤ 0) → (basisTransform P p).Splits) (j : ℕ) :
        0 ≤ (appellCoefficient P (2 * j)).coeff j ∧
          (appellCoefficient P (2 * j)).coeff j ≤
            (appellCoefficient P 2).coeff 1 ^ j / (j.factorial : ℝ)
  • Exact source interval for an interval-operator basis mapRealRooted original

    RealRooted.intervalBasisMap_maps_realRootedIn_iffsource
    theorem intervalBasisMap_maps_realRootedIn_iff
        {alpha beta rho kappa L U : ℝ} {g : ℝ[X]}
        (hLU : L < U) (hrho : 0 < rho) (hkappa : 0 < kappa)
        (htop : 0 < alpha + kappa * g.natDegree)
        (hgpos : HasPosLeadingCoeff g) (hg : IsRealRootedIn (Icc L U) g)
        (S : Set ℝ) :
        (∀ p, IsRealRootedIn S p →
          IsRealRootedIn (Icc L U)
            (intervalBasisMap alpha beta rho kappa L U g p)) ↔
          S ⊆ Icc
            (rho * (alpha * L + beta -
              kappa * (U - L) * g.rootMultiplicity L))
            (rho * (alpha * U + beta +
              kappa * (U - L) * g.rootMultiplicity U))
  • Exact source ray for a ray-operator basis mapRealRooted original

    RealRooted.rayBasisMap_maps_realRootedIn_iffsource
    theorem rayBasisMap_maps_realRootedIn_iff
        {a b kappa h : ℝ} {g : ℝ[X]} (hb : 0 < b) (hkappa : 0 ≤ kappa)
        (hg : IsRealRootedIn (Set.Iic h) g) (S : Set ℝ) :
        (∀ p, IsRealRootedIn S p →
          IsRealRootedIn (Set.Iic h) (rayBasisMap a b kappa h g p)) ↔
          S ⊆ Set.Iic (a + b * h + kappa * g.rootMultiplicity h)
  • For a, b, t ≥ 0 the ray semigroup maps PF polynomials to PF polynomialsRealRooted original

    RealRooted.raySemigroupTransform_isPFPolynomialsource
    theorem raySemigroupTransform_isPFPolynomial {a b t : ℝ}
        (ha : 0 ≤ a) (hb : 0 ≤ b) (ht : 0 ≤ t) {p : ℝ[X]}
        (hp : IsPFPolynomial p) :
        IsPFPolynomial (raySemigroupTransform a b t p)
  • The ray semigroup is conjugate to the rising factorial transform up to a translationRealRooted original

    RealRooted.fallingFactorialTransform_raySemigroupTransformsource
    theorem fallingFactorialTransform_raySemigroupTransform
        (a b t : ℝ) (p : ℝ[X]) :
        Poisson.fallingFactorialTransform (b * t) (raySemigroupTransform a b t p) =
          (basisTransform (risingFactorialPolynomial (b * t)) p).comp
            (X + C (t * a))
  • Time-one ray images of first-order recurrence rows are PFRealRooted original

    RealRooted.rayApplicationSequence_isPFPolynomialsource
    theorem rayApplicationSequence_isPFPolynomial {a b kappa : ℝ} {c : ℕ → ℝ}
        (ha : 0 ≤ a) (hb : 0 ≤ b) (hkappa : 0 ≤ kappa)
        (hc : ∀ n, 0 ≤ c n) (n : ℕ) :
        IsPFPolynomial (rayApplicationSequence a b kappa c n)
  • Finite words of translations and Lah flows with nonnegative parameters preserve PFRealRooted original

    RealRooted.translationLahWordTransform_isPFPolynomialsource
    theorem translationLahWordTransform_isPFPolynomial
        {w : List TranslationLahGenerator} (hw : TranslationLahWordValid w)
        {p : ℝ[X]} (hp : IsPFPolynomial p) :
        IsPFPolynomial (translationLahWordTransform w p)
  • The exponential generating function of a translation–Lah wordRealRooted original

    RealRooted.hasTranslationLahEGF_wordsource
    theorem hasTranslationLahEGF_word (w : List TranslationLahGenerator) :
        HasTranslationLahEGF (translationLahWordBasis w)
          (translationLahWordBeta w) (translationLahWordAtoms w)
  • Every reachable parameter pair (total Lah time, atoms) comes from a valid wordRealRooted original

    RealRooted.TranslationLahParameters.exists_wordsource
    theorem TranslationLahParameters.exists_word
        {β : ℝ} {atoms : List (ℝ × ℝ)}
        (h : TranslationLahParameters β atoms) :
        ∃ w : List TranslationLahGenerator,
          TranslationLahWordValid w ∧
          translationLahWordBeta w = β ∧
          translationLahWordAtoms w = atoms
  • Coefficientwise limits of valid translation–Lah words preserve PFRealRooted original

    RealRooted.IsTranslationLahWordClosure.isPFPolynomial_basisTransformsource
    theorem IsTranslationLahWordClosure.isPFPolynomial_basisTransform
        {T : ℕ → ℝ[X]} (hT : IsTranslationLahWordClosure T)
        {p : ℝ[X]} (hp : IsPFPolynomial p) :
        IsPFPolynomial (basisTransform T p)
  • Hausdorff inequalities for finite positive measures on [0, β]RealRooted original

    RealRooted.sum_alternating_choose_mul_integral_pow_nonnegsource
    theorem sum_alternating_choose_mul_integral_pow_nonneg
        {ν : Measure ℝ} [IsFiniteMeasure ν] {β : ℝ}
        (hsupport : ∀ᵐ u ∂ν, u ∈ Icc 0 β) (j k : ℕ) :
        0 ≤ ∑ i ∈ range (k + 1),
          (-1 : ℝ) ^ i * (Nat.choose k i : ℝ) * β ^ (k - i) *
            (∫ u : ℝ, u ^ (j + i) ∂ν)
  • Hankel (Cauchy–Schwarz) inequality for the first three momentsRealRooted original

    RealRooted.sq_integral_pow_one_le_mul_zero_twosource
    theorem sq_integral_pow_one_le_mul_zero_two
        {ν : Measure ℝ} [IsFiniteMeasure ν] {β : ℝ}
        (hsupport : ∀ᵐ u ∂ν, u ∈ Icc 0 β) :
        (∫ u : ℝ, u ^ 1 ∂ν) ^ 2 ≤
          (∫ u : ℝ, u ^ 0 ∂ν) * ∫ u : ℝ, u ^ 2 ∂ν
  • An eventually geometric basis with vanishing discrepancies is p ↦ P₀ · p(y)RealRooted original

    RealRooted.linearMap_eq_mul_comp_of_eventually_geometricsource
    theorem linearMap_eq_mul_comp_of_eventually_geometric
        (T : ℝ[X] →ₗ[ℝ] ℝ[X]) (P : ℕ → ℝ[X])
        {y : ℝ[X]} {k : ℕ} (hT : ∀ n, T (X ^ n) = P n)
        (hk : k ≠ 0) (hy : y ≠ 0)
        (htail : ∀ n, k ≤ n → P n = P k * y ^ (n - k))
        (hdiscrepancy : ∀ j < k, geometricDiscrepancy P y k j = 0) :
        ∀ p, T p = P 0 * p.comp y
  • A nonzero prefix discrepancy gives a shifted power with non-real-rooted imageRealRooted original

    RealRooted.exists_not_splits_shiftedPower_of_eventually_geometricsource
    theorem exists_not_splits_shiftedPower_of_eventually_geometric
        (T : ℝ[X] →ₗ[ℝ] ℝ[X]) {P : ℕ → ℝ[X]} {a d r : ℝ} {k : ℕ}
        (hT : ∀ n, T (X ^ n) = P n)
        (hd : d ≠ 0) (hPk : P k ≠ 0)
        (htail : ∀ n, k ≤ n →
          P n = P k * (C a + C d * X) ^ (n - k))
        (hexists : ∃ j < k,
          geometricDiscrepancy P (C a + C d * X) k j ≠ 0)
        (hr : r ≠ 0) :
        let D
  • A scalar-index recurrence factors through the rising factorial transformRealRooted original

    RealRooted.basisMap_factorization_of_scalarIndex_recurrencesource
    theorem basisMap_factorization_of_scalarIndex_recurrence
        {M : Type*} [AddCommGroup M] [Module ℝ M]
        (P : ℕ → M) (L : Module.End ℝ M) (h : ℝ) (g : M)
        (hzero : P 0 = g)
        (hsucc : ∀ n, P (n + 1) = L (P n) + ((n : ℝ) * h) • P n) :
        Polynomial.lsum (fun n => LinearMap.toSpanSingleton ℝ M (P n)) =
          (polynomialOrbitMap L g).comp
            (Polynomial.basisTransformₗ (risingFactorialPolynomial h))
  • The finite Borcea–Brändén symbol of a basis transformRealRooted original

    RealRooted.BorceaBranden.finiteAlgebraicSymbol_basisTransformₗsource
    theorem finiteAlgebraicSymbol_basisTransformₗ (P : ℕ → ℝ[X]) (d : ℕ) :
        finiteAlgebraicSymbol d (Polynomial.basisTransformₗ P) =
          ∑ k ∈ Finset.range (d + 1),
            MvPolynomial.C (Nat.choose d k : ℝ) *
              polynomialInFirstMv (P k) *
                MvPolynomial.X (1 : Fin 2) ^ (d - k)
  • A stable finite symbol gives degree-bounded real-rootedness preservationRealRooted original

    RealRooted.BorceaBranden.basisTransform_splits_or_zero_of_finiteSymbol_stablesource
    theorem basisTransform_splits_or_zero_of_finiteSymbol_stable
        {P : ℕ → ℝ[X]} {d : ℕ} {p : ℝ[X]}
        (hSymbol : MvUpperHalfPlaneStable
          (complexifyMv
            (∑ k ∈ Finset.range (d + 1),
              MvPolynomial.C (Nat.choose d k : ℝ) *
                polynomialInFirstMv (P k) *
                  MvPolynomial.X (1 : Fin 2) ^ (d - k))))
        (hpdeg : p.natDegree ≤ d) (hp : p.Splits) :
        Polynomial.basisTransform P p = 0 ∨
          (Polynomial.basisTransform P p).Splits
  • A stable finite symbol and nonnegative rows give degree-bounded PF preservationRealRooted original

    RealRooted.BorceaBranden.basisTransform_isPF_of_finiteSymbol_stablesource
    theorem basisTransform_isPF_of_finiteSymbol_stable
        {P : ℕ → ℝ[X]} {d : ℕ} {p : ℝ[X]}
        (hSymbol : MvUpperHalfPlaneStable
          (complexifyMv
            (∑ k ∈ Finset.range (d + 1),
              MvPolynomial.C (Nat.choose d k : ℝ) *
                polynomialInFirstMv (P k) *
                  MvPolynomial.X (1 : Fin 2) ^ (d - k))))
        (hP : ∀ k, k ≤ d → HasNonnegCoeffs (P k))
        (hpdeg : p.natDegree ≤ d) (hp : IsPFPolynomial p) :
        IsPFPolynomial (Polynomial.basisTransform P p)

Lean source RealRooted/Challenges/Preservers/BasisTransformPreservers.lean at revision d6670742. Formalized 2026-11-03.