Jacobi polynomials

The shifted Jacobi polynomials are orthogonal on $(0,1)$, so they have simple roots in $(0,1)$ and consecutive ones interlace. A related family with positive coefficients contains the Narayana polynomials and changes its parameters under differentiation and Euler operators.

Results

For real $\alpha,\beta$ the shifted Jacobi polynomial is $$ P_n^{(\alpha,\beta)}(x) = \sum_{k=0}^{n} (-1)^k \binom{n + \alpha}{n - k} \binom{n + \alpha + \beta + k}{k} x^k, $$ with generalized binomial coefficients; it is the classical Jacobi polynomial at $1 - 2x$. The monic version divides by the leading coefficient $(-1)^n \binom{2n + \alpha + \beta}{n}$.

Theorem (roots and interlacing). Let $\alpha, \beta > -1$ and $n \ge 0$.

For $\alpha,\beta>-1$ and every real polynomial $q$ with $\deg q < n$, $$\int_0^1 P_n^{(\alpha,\beta)}(x)\, q(x)\, x^\alpha (1 - x)^\beta \, dx = 0,$$ and the monic polynomials satisfy a Favard three-term recurrence with explicit coefficients. The shifted Legendre polynomials are the case $\alpha=\beta=0$.

Theorem (Markoff). For $i<n$, the $i$-th smallest root of the monic polynomial with parameters $(\alpha, 1)$ is strictly increasing in $\alpha\in(-1,\infty)$.

For $n\ge0$ and real $a,b$ let $$ H_n^{(a,b)}(x)=\sum_{k=0}^n\frac{\binom nk\binom{n+b}{k}}{\binom{a+k}{k}}\,x^k . $$ On the diagonal $a=b=m$ this is the Narayana polynomial.

Theorem (positive-coefficient family). Let $a,b>-1$. Then $H_n^{(a,b)}$ has positive coefficients, degree $n$ and constant term $1$. It is a Pólya frequency polynomial with simple negative roots, and $H_n^{(a,b)}\ll H_{n+1}^{(a,b)}$ with no common root.

Differentiation shifts the first parameter: $\bigl(H_{n+1}^{(a,b)}\bigr)'=\frac{(n+1)(n+b+1)}{a+1}H_n^{(a+1,b)}$, and the $r$-th derivative shifts $a$ to $a+r$. A first-order derivative recurrence in $n$, together with $H_0$ and $H_1$, determines the family. With $\theta=x\,d/dx$, the operator $\prod_{j<r}(\theta+a+j)$ multiplies the coefficient of $x^k$ by $(k+a)_r$ and preserves Pólya frequency polynomials for $a\ge0$; for $a>-1$, $H_n^{(a,a+r)}$ is a constant multiple of this operator with parameter $a+1$ applied to $H_n^{(a+r,a+r)}$. Conversely, for $a,b>-1$ there is a polynomial $p$ with $H_n^{(a,b)}=\sum_kp(k)\,[x^k]H_n^{(b,b)}\,x^k$ for all $n$ if and only if $b=a+r$ with $r\in\mathbb N$, and then $p(x)=(x+a+1)_r/(a+1)_r$. Here $(y)_r$ is the rising factorial.

Finally, let $L_{n,\alpha,\beta}$ be the differential operator whose coefficient recurrence is $$ (k+1)(k+\alpha+1)\,p_{k+1}+\bigl(k(k+\alpha+\beta+1)-n(n+\alpha+\beta+1)\bigr)p_k=0, $$ so that $L_{n,\alpha,\beta}\,P_n^{(\alpha,\beta)}(-x)=0$. For $\alpha>-1$ a polynomial solution is determined by its constant term. If $\beta=-m$ with $m\le n$, every polynomial solution is a multiple of $(1+x)^m\,P_{n-m}^{(\alpha,m)}(-x)$. A nonzero solution therefore has degree $n$, real roots, and the root $-1$ with multiplicity exactly $m$; if its constant term is nonnegative, its coefficients form a Pólya frequency sequence.

References

  1. [Sze39] G. Szegő. Orthogonal Polynomials. Colloquium Publications, American Mathematical Society, 1939.
    BibTeX
    @book{Szego1939,
      author = {Szegő, G.},
      title = {Orthogonal {P}olynomials},
      year = {1939},
      series = {Colloquium Publications},
      publisher = {American Mathematical Society},
      isbn = {9781470431716},
      doi = {10.1090/coll/023},
      url = {https://doi.org/10.1090/coll/023}
    }

Definitions

  • Shifted Jacobi polynomials

    Polynomial.shiftedJacobisource
    noncomputable def shiftedJacobi (n : ℕ) (α β : ℝ) : ℝ[X] :=
      ∑ k ∈ range (n + 1),
        C ((-1 : ℝ) ^ k * Ring.choose (n + α) (n - k) *
          Ring.choose (n + α + β + k) k) * X ^ k
  • Monic shifted Jacobi polynomials

    Polynomial.shiftedJacobiMonicsource
    noncomputable def shiftedJacobiMonic (n : ℕ) (α β : ℝ) : ℝ[X] :=
      C (((-1 : ℝ) ^ n * Ring.choose (n + α + β + n) n)⁻¹) *
        shiftedJacobi n α β
  • The weight x^α (1 - x)^β

    RealRooted.shiftedJacobiWeightsource
    def shiftedJacobiWeight (α β x : ℝ) : ℝ :=
      x ^ α * (1 - x) ^ β
  • The i-th smallest root of the monic polynomial

    RealRooted.shiftedJacobiMonicRootsource
    noncomputable def shiftedJacobiMonicRoot (n : ℕ) (i : Fin n)
        (α β : ℝ) : ℝ :=
      ((shiftedJacobiMonic n α β).roots.sort (· ≤ ·)).getD i 0
  • The positive-coefficient Jacobi family Σ C(n,k) C(n+b,k) / C(a+k,k) X^k

    RealRooted.jacobiCoefficientPolynomialsource
    noncomputable def jacobiCoefficientPolynomial (n : ℕ) (a b : ℝ) : ℝ[X] :=
      ∑ k ∈ range (n + 1), C (jacobiCoefficient n k a b) * X ^ k
  • The reflected shifted-Jacobi differential operator

    RealRooted.reflectedJacobiOperatorsource
    def reflectedJacobiOperator (n : ℕ) (alpha beta : ℝ) (p : ℝ[X]) : ℝ[X] :=
      X * (1 + X) * p.derivative.derivative +
        (C (alpha + 1) + C (alpha + beta + 2) * X) * p.derivative -
        C (n * (n + alpha + beta + 1)) * p

Theorems

  • Consecutive shifted Jacobi polynomials interlaceMain result

    RealRooted.shiftedJacobi_interlaces_succsource
    theorem shiftedJacobi_interlaces_succ (n : ℕ) {α β : ℝ}
        (hα : -1 < α) (hβ : -1 < β) :
        Interlaces (shiftedJacobi n α β) (shiftedJacobi (n + 1) α β)
  • Shifted Jacobi polynomials are real-rooted

    RealRooted.shiftedJacobi_splitssource
    theorem shiftedJacobi_splits (n : ℕ) {α β : ℝ}
        (hα : -1 < α) (hβ : -1 < β) :
        (shiftedJacobi n α β).Splits
  • Shifted Jacobi polynomials have simple roots

    RealRooted.shiftedJacobi_hasSimpleRootssource
    theorem shiftedJacobi_hasSimpleRoots (n : ℕ) {α β : ℝ}
        (hα : -1 < α) (hβ : -1 < β) :
        HasSimpleRoots (shiftedJacobi n α β)
  • Every root lies in (0, 1)

    RealRooted.shiftedJacobi_isRoot_mem_Ioosource
    theorem shiftedJacobi_isRoot_mem_Ioo (n : ℕ) {α β r : ℝ}
        (hα : -1 < α) (hβ : -1 < β)
        (hr : (shiftedJacobi n α β).IsRoot r) :
        r ∈ Set.Ioo (0 : ℝ) 1
  • Monic shifted Jacobi polynomials satisfy a Favard recurrence

    RealRooted.shiftedJacobiMonic_satisfiesFavardRecurrencesource
    theorem shiftedJacobiMonic_satisfiesFavardRecurrence (α β : ℝ)
        (hα : -1 < α) (hβ : -1 < β) :
        SatisfiesFavardRecurrence
          (fun n ↦ shiftedJacobiMonic n α β)
          (fun n ↦ shiftedJacobiDiag n α β)
          (fun n ↦ shiftedJacobiSubdiag n α β)
  • Orthogonality on (0, 1) for the weight x^α (1 - x)^β

    RealRooted.shiftedJacobi_integral_orthogonalsource
    theorem shiftedJacobi_integral_orthogonal
        {α β : ℝ} (hα : -1 < α) (hβ : -1 < β) {n : ℕ}
        (q : ℝ[X]) (hq : q.natDegree < n) :
        (∫ x : ℝ in 0..1,
          (shiftedJacobi n α β).eval x * q.eval x *
            shiftedJacobiWeight α β x) = 0
  • P_n^(α+1,β+1) interlaces P_{n+1}^(α,β)

    RealRooted.shiftedJacobi_interlaces_shift_bothsource
    theorem shiftedJacobi_interlaces_shift_both (n : ℕ) {α β : ℝ}
        (hα : -1 < α) (hβ : -1 < β) :
        Interlaces (shiftedJacobi n (α + 1) (β + 1))
          (shiftedJacobi (n + 1) α β)
  • Raising α by one: roots alternate and move right

    RealRooted.shiftedJacobiMonic_strictInterl_alpha_add_onesource
    theorem shiftedJacobiMonic_strictInterl_alpha_add_one (n : ℕ) {α β : ℝ}
        (hα : -1 < α) (hβ : -1 < β) :
        StrictInterl (shiftedJacobiMonic n α β)
          (shiftedJacobiMonic n (α + 1) β)
  • Roots increase strictly with α for β = 1

    RealRooted.strictMonoOn_shiftedJacobiMonicRoot_alphasource
    theorem strictMonoOn_shiftedJacobiMonicRoot_alpha
        (n : ℕ) (i : Fin n) :
        StrictMonoOn (fun a => shiftedJacobiMonicRoot n i a 1)
          (Set.Ioi (-1 : ℝ))
  • Shifted Legendre polynomials are the case α = β = 0

    RealRooted.shiftedLegendreReal_eq_shiftedJacobisource
    theorem shiftedLegendreReal_eq_shiftedJacobi (n : ℕ) :
        shiftedLegendreReal n = Polynomial.shiftedJacobi n 0 0
  • Shifted Legendre polynomials are real-rooted

    RealRooted.shiftedLegendreReal_splitssource
    theorem shiftedLegendreReal_splits (n : ℕ) :
        (shiftedLegendreReal n).Splits
  • Consecutive shifted Legendre polynomials interlace

    RealRooted.shiftedLegendreReal_strictInterl_succsource
    theorem shiftedLegendreReal_strictInterl_succ (n : ℕ) :
        StrictInterl (shiftedLegendreReal n) (shiftedLegendreReal (n + 1))
  • For a, b > -1 the family is Pólya frequency

    RealRooted.jacobiCoefficientPolynomial_isPFPolynomialsource
    theorem jacobiCoefficientPolynomial_isPFPolynomial
        (n : ℕ) {a b : ℝ} (ha : -1 < a) (hb : -1 < b) :
        IsPFPolynomial (jacobiCoefficientPolynomial n a b)
  • Consecutive polynomials of the family interlace

    RealRooted.jacobiCoefficientPolynomial_strictInterl_succsource
    theorem jacobiCoefficientPolynomial_strictInterl_succ
        (n : ℕ) {a b : ℝ} (ha : -1 < a) (hb : -1 < b) :
        StrictInterl (jacobiCoefficientPolynomial n a b)
          (jacobiCoefficientPolynomial (n + 1) a b)
  • The family has simple, negative roots

    RealRooted.jacobiCoefficientPolynomial_hasSimpleRootssource
    theorem jacobiCoefficientPolynomial_hasSimpleRoots
        (n : ℕ) {a b : ℝ} (ha : -1 < a) (hb : -1 < b) :
        HasSimpleRoots (jacobiCoefficientPolynomial n a b)
  • On the diagonal a = b = m the family is the Narayana polynomial

    RealRooted.jacobiCoefficientPolynomial_nat_diagonalsource
    theorem jacobiCoefficientPolynomial_nat_diagonal (m n : ℕ) :
        jacobiCoefficientPolynomial n m m = narayanaPolynomial m n
  • Differentiation shifts the parameter a to a + 1

    RealRooted.derivative_jacobiCoefficientPolynomialsource
    theorem derivative_jacobiCoefficientPolynomial (n : ℕ) {a b : ℝ}
        (ha : -1 < a) :
        (jacobiCoefficientPolynomial (n + 1) a b).derivative =
          C (((n + 1 : ℕ) : ℝ) * (n + b + 1) / (a + 1)) *
            jacobiCoefficientPolynomial n (a + 1) b
  • A first-order derivative recurrence in the degree

    RealRooted.jacobiCoefficientPolynomial_derivative_recurrencesource
    theorem jacobiCoefficientPolynomial_derivative_recurrence
        (n : ℕ) {a b : ℝ} (ha : -1 < a) (hb : -1 < b) :
        C (jacobiCoefficientRecurrenceDen n a b) *
            jacobiCoefficientPolynomial (n + 1) a b =
          (C (jacobiCoefficientRecurrenceDen n a b) +
              C (jacobiCoefficientXWeight n a b) * X) *
              jacobiCoefficientPolynomial n a b +
            (C (jacobiCoefficientDerivativeWeight n a b) * X * (1 - X)) *
              (jacobiCoefficientPolynomial n a b).derivative
  • The derivative recurrence with two initial values determines the family

    RealRooted.eq_jacobiCoefficientPolynomial_of_derivative_recurrencesource
    theorem eq_jacobiCoefficientPolynomial_of_derivative_recurrence
        (P : ℕ → ℝ[X]) {a b : ℝ} (ha : -1 < a) (hb : -1 < b)
        (hzero : P 0 = jacobiCoefficientPolynomial 0 a b)
        (hone : P 1 = jacobiCoefficientPolynomial 1 a b)
        (hrec : ∀ n, 1 ≤ n →
          C (jacobiCoefficientRecurrenceDen n a b) * P (n + 1) =
            (C (jacobiCoefficientRecurrenceDen n a b) +
                C (jacobiCoefficientXWeight n a b) * X) * P n +
              (C (jacobiCoefficientDerivativeWeight n a b) * X * (1 - X)) *
                (P n).derivative) :
        ∀ n, P n = jacobiCoefficientPolynomial n a b
  • For β = -m the polynomial solutions are multiples of (1 + X)^m times a Jacobi polynomial

    RealRooted.eq_C_mul_endpoint_factor_of_reflectedJacobiOperator_eq_zerosource
    theorem eq_C_mul_endpoint_factor_of_reflectedJacobiOperator_eq_zero
        (n m : ℕ) {alpha : ℝ} (halpha : -1 < alpha) (hmn : m ≤ n)
        {p : ℝ[X]} (hp : reflectedJacobiOperator n alpha (-(m : ℝ)) p = 0) :
        p =
          C (p.coeff 0 * (Ring.choose ((n - m : ℕ) + alpha) (n - m))⁻¹) *
            ((1 + X) ^ m * (shiftedJacobi (n - m) alpha m).comp (-X))
  • Polynomial solutions are determined by their constant term

    RealRooted.eq_of_reflectedJacobiOperator_eq_zerosource
    theorem eq_of_reflectedJacobiOperator_eq_zero
        (n : ℕ) {alpha beta : ℝ} (halpha : -1 < alpha) {p q : ℝ[X]}
        (hcoeff : p.coeff 0 = q.coeff 0)
        (hp : reflectedJacobiOperator n alpha beta p = 0)
        (hq : reflectedJacobiOperator n alpha beta q = 0) :
        p = q
  • Polynomial solutions at a negative integer endpoint are real-rooted

    RealRooted.splits_of_reflectedJacobiOperator_eq_zerosource
    theorem splits_of_reflectedJacobiOperator_eq_zero
        (n m : ℕ) {alpha : ℝ} (halpha : -1 < alpha) (hmn : m ≤ n)
        {p : ℝ[X]} (hp : reflectedJacobiOperator n alpha (-(m : ℝ)) p = 0) :
        p.Splits
  • The root -1 has multiplicity exactly m

    RealRooted.rootMultiplicity_neg_one_of_reflectedJacobiOperator_eq_zerosource
    theorem rootMultiplicity_neg_one_of_reflectedJacobiOperator_eq_zero
        (n m : ℕ) {alpha : ℝ} (halpha : -1 < alpha) (hmn : m ≤ n)
        {p : ℝ[X]} (hp : reflectedJacobiOperator n alpha (-(m : ℝ)) p = 0)
        (hpne : p ≠ 0) :
        p.rootMultiplicity (-1) = m
  • The coefficients of a solution with p(0) ≥ 0 form a Pólya frequency sequence

    RealRooted.isPolyaFreqSeq_coeff_of_reflectedJacobiOperator_eq_zerosource
    theorem isPolyaFreqSeq_coeff_of_reflectedJacobiOperator_eq_zero
        (n m : ℕ) {alpha : ℝ} (halpha : -1 < alpha) (hmn : m ≤ n)
        {p : ℝ[X]} (hp : reflectedJacobiOperator n alpha (-(m : ℝ)) p = 0)
        (hpzero : 0 ≤ p.coeff 0) :
        IsPolyaFreqSeq p.coeff
  • Shifting b = a to b = a + r is a product of r consecutive Euler operators

    RealRooted.jacobiCoefficientPolynomial_eq_C_mul_eulerShiftRangesource
    theorem jacobiCoefficientPolynomial_eq_C_mul_eulerShiftRange
        (a : ℝ) (r n : ℕ) (ha : -1 < a) :
        jacobiCoefficientPolynomial n a (a + r) =
          C (risingFactorial (a + 1) r)⁻¹ *
            eulerShiftRange (a + 1) r
              (jacobiCoefficientPolynomial n (a + r) (a + r))
  • The r-th derivative shifts the parameter a to a + r

    RealRooted.iterate_derivative_jacobiCoefficientPolynomialsource
    theorem iterate_derivative_jacobiCoefficientPolynomial
        (a b : ℝ) (r n : ℕ) (ha : -1 < a) :
        (derivative^[r]) (jacobiCoefficientPolynomial (n + r) a b) =
          C (risingFactorial ((n : ℝ) + 1) r *
              risingFactorial ((n : ℝ) + b + 1) r /
                risingFactorial (a + 1) r) *
            jacobiCoefficientPolynomial n (a + r) b
  • A polynomial Euler multiplier maps the diagonal family to (a, b) iff b - a is natural

    RealRooted.exists_diagonalOperator_jacobiCoefficientPolynomial_iffsource
    theorem exists_diagonalOperator_jacobiCoefficientPolynomial_iff
        {a b : ℝ} (ha : -1 < a) (hb : -1 < b) :
        (∃ p : ℝ[X], ∀ n,
          jacobiCoefficientPolynomial n a b =
            diagonalOperator (fun k ↦ p.eval (k : ℝ))
              (jacobiCoefficientPolynomial n b b)) ↔
          ∃ r : ℕ, b = a + r
  • Consecutive Euler operators preserve Pólya frequency polynomials

    RealRooted.IsPFPolynomial.eulerShiftRangesource
    theorem IsPFPolynomial.eulerShiftRange {p : ℝ[X]} (hp : IsPFPolynomial p)
        {a : ℝ} (ha : 0 ≤ a) (r : ℕ) :
        IsPFPolynomial (eulerShiftRange a r p)

Lean source RealRooted/Challenges/Orthogonal/JacobiPolynomials.lean at revision d6670742. Formalized 2026-09-07.